Can someone create league of legend's Lissandra's Q for me? :)

[old]

Lissandra's ice shard, point target skill that when hit someone split in small pieces damaging everything near.

 

[StormKnight]

well
Never played lol ( i know its wierd)
tell me more details of this spell

 

[Devalut]

Skill shot projectile that breaks on the first hit unit spreading shards into a wider radius behind the first hit unit dealing the same damage.
Targets hit are slowed for a bit

Ice shard is the ability (thought I copied at time)

Edit, this is rather difficult :O

 

[Tasyen]

So this is basicly a skillshot slowing the main target and then shoting kind of a shockwave?
Is the travel distance of the shockwave a constant one (hit and then travel further x range) or does it travel a bigger total range when hit? I can't see that out of the video.

 

[StormKnight]

i think someone made this as a spell in hive
he was also included in the video where hive was showing 5 people and the very nice spells they made .
i also remember that
KILLCIDE
made a chain lightning ability as a request for someone
that acts exactly how you want you can go and find his workshop and learn
how to make the ability and make a frost version yourself.
or just ask him to make it for you since he did it once

 

[Devalut]

@Tasyen
- The initial projectile is small and opens up slightly wider
- The range is short if it hits nothing and extends 1/3 farther if it hits something

I thought of unit missile but I got lost into inception like unit groups within unit groups that would require aoe and not to mention "cone" like area.

@Storm Knight
The way in which the ability is activated and behaves after hitting a target are much more than point and click aoe.
That is, if you're referring to "smite" that KILLCIDE made in his SR workshop.

 

[KILLCIDE]

Ahh yeah. The "Smite" ability I made sounds exactly like that the only problem is that Smite is target unit, and after the primary target, the ability will look for the X closest units to damage (regardless of angle, which I think goes against the original concept of Lissandra's Q).

Here it is for anyone interested: Spell Request Workshop

 

[Tasyen]

Wrote such a spell (with spell system), it should be like lissandras q or be changeable to be like it.

I thought of unit missile but I got lost into inception like unit groups within unit groups that would require aoe and not to mention "cone" like area.

From the videos i watched it does not deal cone damage, it deals damge in a line (why i said shockwave).

Triggers

• Ice Shard Init
  • Events
    • Map initialization
  • Conditions
  • Actions
    • Set Spell__Ability = Ice Shard
    • Set IceShard_Slow = Slow (Ice Shard)
    • -------- Index 0 = until the first target was hit. --------
    • -------- Index 1 after the first target was hit. --------
    • Set IceShard_Damage_Base[0] = 40.00
    • Set IceShard_Damage_Add[0] = 30.00
    • Set IceShard_Damage_Base[1] = 40.00
    • Set IceShard_Damage_Add[1] = 30.00
    • Set IceShard_AoE[0] = 40.00
    • Set IceShard_AoE[1] = 100.00
    • Set IceShard_Speed[0] = 700.00
    • Set IceShard_Speed[1] = 700.00
    • Set IceShard_Range[0] = 800.00
    • Set IceShard_Range[1] = 400.00
    • -------- when hitting the first target is the remaning traveldistance added (true, -> resulting hit range range[0] +range[1]) or droped (false) --------
    • Set IceShard_AddDistance = True
    • Set IceShard_Model[0] = Abilities\Weapons\LichMissile\LichMissile.mdl
    • Set IceShard_Model[1] = Abilities\Spells\Orc\Shockwave\ShockwaveMissile.mdl
    • -------- scale of the models used, in procent, 100 = normal size 200 = 2 x normal size --------
    • Set IceShard_Scale[0] = 100.00
    • Set IceShard_Scale[1] = 100.00
    • -------- On Hit EffectModel --------
    • Set IceShard_Model_OnHit[0] = <Leerer String>
    • Set IceShard_Model_OnHit[1] = Abilities\Weapons\LichMissile\LichMissile.mdl
    • -------- Uses an empty string to display the effect on the current position (won't follow). --------
    • Set IceShard_Model_OnHitAttach[0] = <Leerer String>
    • Set IceShard_Model_OnHitAttach[1] = chest
    • -------- Targeting --------
    • Set Spell__Filter_AllowEnemy = True
    • Set Spell__Filter_AllowLiving = True
    • Set Spell__Filter_AllowHero = True
    • Set Spell__Filter_AllowNonHero = True
    • Set Spell__Filter_AllowAlly = False
    • Set Spell__Filter_AllowDead = False
    • Set Spell__Filter_AllowFlying = False
    • Set Spell__Filter_AllowMechanical = False
    • Set Spell__Filter_AllowStructure = False
    • Set Spell__Filter_AllowMagicImmune = False
    • -------- Don'Touch below --------
    • Set Spell__Trigger_OnEffect = Ice Shard Cast <gen>
    • Set Spell__Trigger_OnLoop = Ice Shard Loop First <gen>
    • Set Spell__UseTargetGroup = True
    • Set Spell__AutoAddTargets = True
    • Set Spell__Time = 0.05
    • Set Spell__Duration = (IceShard_Range[0] / IceShard_Speed[0])
    • Trigger - Run Spell System <gen> (ignoring conditions)
    • Unit - Add IceShard_Slow to Spell_i_PreloadDummy
    • Unit - Remove IceShard_Slow from Spell_i_PreloadDummy

• Ice Shard Cast
  • Events
  • Conditions
  • Actions
    • Set Spell_Damage[Spell__Index] = (IceShard_Damage_Base[0] + (IceShard_Damage_Add[0] x Spell__LevelMultiplier))
    • Set Spell_Damage2[Spell__Index] = (IceShard_Damage_Base[1] + (IceShard_Damage_Add[1] x Spell__LevelMultiplier))
    • -------- Now add your Maps custom scaling mechanic like spellpower. --------
    • Set Spell_Damage[Spell__Index] = (Spell_Damage[Spell__Index] + (0.70 x (Real((Intelligence of Spell__Caster (Include bonuses))))))
    • Set Spell_Damage2[Spell__Index] = (Spell_Damage2[Spell__Index] + (0.70 x (Real((Intelligence of Spell__Caster (Include bonuses))))))
    • -------- ---- --------
    • Unit - Create 1 Spell__DummyType for Spell__DummyOwner at Spell__CastPoint facing (Angle from Spell__CastPoint to Spell__TargetPoint) degrees
    • Set Spell_Dummy[Spell__Index] = (Last created unit)
    • Animation - Change Spell_Dummy[Spell__Index]'s size to (IceShard_Scale[0]%, IceShard_Scale[0]%, IceShard_Scale[0]%) of its original size
    • Animation - Change Spell_Dummy[Spell__Index] flying height to 70.00 at 0.00
    • Custom script: set udg_Spell_Grafic[udg_Spell__Index] = AddSpecialEffectTarget( udg_IceShard_Model[0] , udg_Spell_Dummy[udg_Spell__Index], "origin" )
    • Set Spell_Speed[Spell__Index] = (IceShard_Speed[0] x 0.05)
    • Set Spell__StartDuration = True

• Ice Shard Loop First
  • Events
  • Conditions
  • Actions
    • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      • If - Conditions
        • Spell__Expired Equal to True
      • Then - Actions
        • Special Effect - Destroy Spell_Grafic[Spell__Index]
        • Unit - Add a 0.01 second Generic expiration timer to Spell_Dummy[Spell__Index]
      • Else - Actions
        • Trigger - Run Ice Shard Move <gen> (ignoring conditions)
        • Set Spell__InRangePoint = (Position of Spell_Dummy[Spell__Index])
        • Set Spell__InRangeMax = 1
        • Set Spell__InRange = IceShard_AoE[0]
        • Custom script: call RemoveLocation(udg_Spell__InRangePoint)
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • Spell__InRangeCount Not equal to 0
          • Then - Actions
            • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              • If - Conditions
                • IceShard_Model_OnHitAttach[0] Equal to <Leerer String>
              • Then - Actions
                • Custom script: call DestroyEffect( AddSpecialEffect( udg_IceShard_Model_OnHit[0] , GetUnitX(udg_Spell__InRangeUnits[1]), GetUnitY(udg_Spell__InRangeUnits[1]) ) )
              • Else - Actions
                • Custom script: call DestroyEffect( AddSpecialEffectTarget( udg_IceShard_Model_OnHit[0] , udg_Spell__InRangeUnits[1], udg_IceShard_Model_OnHitAttach[0] ) )
            • Unit - Cause Spell__Caster to damage Spell__InRangeUnits[1], dealing Spell_Damage[Spell__Index] damage of attack type Spells and damage type Magic
            • Unit - Add IceShard_Slow to Spell_i_PreloadDummy
            • Unit - Set level of IceShard_Slow for Spell_i_PreloadDummy to Spell__Level
            • Unit - Order Spell_i_PreloadDummy to Menschen-Zauberin - 'Slow' Spell__InRangeUnits[1]
            • Unit - Remove IceShard_Slow from Spell_i_PreloadDummy
            • Special Effect - Destroy Spell_Grafic[Spell__Index]
            • Custom script: set udg_Spell_Grafic[udg_Spell__Index] = AddSpecialEffectTarget( udg_IceShard_Model[1] , udg_Spell_Dummy[udg_Spell__Index], "origin" )
            • Set Spell__Trigger_OnLoop = Ice Shard Loop Further <gen>
            • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
              • If - Conditions
                • IceShard_AddDistance Equal to True
              • Then - Actions
                • -------- Convert Remaning Duration into Duration based on speed[1] --------
                • Set Spell__Duration = (Spell__Duration x (IceShard_Speed[0] / IceShard_Speed[1]))
                • Set Spell__Duration = (Spell__Duration + (IceShard_Range[1] / IceShard_Speed[1]))
              • Else - Actions
                • Set Spell__Duration = (IceShard_Range[1] / IceShard_Speed[1])
            • Animation - Change Spell_Dummy[Spell__Index]'s size to (IceShard_Scale[1]%, IceShard_Scale[1]%, IceShard_Scale[1]%) of its original size
            • Set Spell_Speed[Spell__Index] = (IceShard_Speed[1] x 0.05)
          • Else - Actions

• Ice Shard Loop Further
  • Events
  • Conditions
  • Actions
    • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
      • If - Conditions
        • Spell__Expired Equal to True
      • Then - Actions
        • Special Effect - Destroy Spell_Grafic[Spell__Index]
        • Unit - Add a 0.01 second Generic expiration timer to Spell_Dummy[Spell__Index]
      • Else - Actions
        • Trigger - Run Ice Shard Move <gen> (ignoring conditions)
        • Set Spell__InRangePoint = (Position of Spell_Dummy[Spell__Index])
        • Set Spell__InRange = IceShard_AoE[1]
        • Custom script: call RemoveLocation(udg_Spell__InRangePoint)
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • IceShard_Model_OnHitAttach[1] Equal to <Leerer String>
          • Then - Actions
            • Unit Group - Pick every unit in Spell__InRangeGroup and do (Actions)
              • Loop - Actions
                • Set Spell__InRangeUnit = (Picked unit)
                • Custom script: call DestroyEffect( AddSpecialEffect( udg_IceShard_Model_OnHit[1] , GetUnitX(udg_Spell__InRangeUnit), GetUnitY(udg_Spell__InRangeUnit) ) )
                • Unit - Cause Spell__Caster to damage Spell__InRangeUnit, dealing Spell_Damage2[Spell__Index] damage of attack type Spells and damage type Magic
          • Else - Actions
            • Unit Group - Pick every unit in Spell__InRangeGroup and do (Actions)
              • Loop - Actions
                • Set Spell__InRangeUnit = (Picked unit)
                • Custom script: call DestroyEffect( AddSpecialEffectTarget( udg_IceShard_Model_OnHit[1] , udg_Spell__InRangeUnit, udg_IceShard_Model_OnHitAttach[1] ) )
                • Unit - Cause Spell__Caster to damage Spell__InRangeUnit, dealing Spell_Damage2[Spell__Index] damage of attack type Spells and damage type Magic

• Ice Shard Move
  • Events
  • Conditions
  • Actions
    • Set MoveLoc[0] = (Position of Spell_Dummy[Spell__Index])
    • Set MoveLoc[1] = (MoveLoc[0] offset by Spell_Speed[Spell__Index] towards (Facing of Spell_Dummy[Spell__Index]) degrees)
    • Unit - Move Spell_Dummy[Spell__Index] instantly to MoveLoc[1]
    • Custom script: call RemoveLocation(udg_MoveLoc[0])
    • Custom script: call RemoveLocation(udg_MoveLoc[1])