[JASS] Correct use of LocalPlayer()

Kixer · May 12, 2007

Could someone please enlighten me on how to correctly use LocalPlayer().
Ive heard alot of people saying that LocalPlayer Desyncs a game but iv never heard when or why.
I'd also like to know how to use LocalPlayer so lets say only certian players can see Floating Text, Multiboards ect.
And could someone maybe list other usefull uses of LocalPlayer().
Thanks in advanced!

Diablo-dk · May 12, 2007

Using GetLocalPlayer() is actually pretty simple, you just need to know when to use it and when not to use it
To do an action for one player(example showing texttag)

JASS:

if GetLocalPlayer() == WhichPlayer then
call SetTextTagVisibillity(sometexttag, false)
endif

Inside this "if" box, all actions will be done for "WhichPlayer"
another way to use it is like this:

JASS:

call SetTextTagVisibillity(sometexttag,GetLocalPlayer() == WhichPlayer)

Desyncs usually happens when you create an object or change gameplay for one player,
like this:

JASS:

local integer unitid='h000'
if GetLocalPlayer() == WhichPlayer then
set unitid='e000'
endif
call CreateUnit(player,unitid,x,y,180)

this will create the unit 'h000' for all players except WhichPlayer, who will have the unit as 'e000'.
this will cause a desynce = server split.

GetLocalPlayer() is also usefull for showing multiboards, special effects etc. for other players.

Kixer · May 12, 2007

I see,

Thanks Diablo, i had the general idea about GetLocalPlayer() = WhichPlayer but i had no idea about the game Desync'ing.

Thanks again!

PurplePoot · May 12, 2007

Diablo, funnily enough, that causes a desynch when the unit dies, not when it's created, if it has the same damage, life, etc (though the model, name, and scale can change)

(and the owner of the killer/dier won't get desynched)

paskovich · May 12, 2007

And what about cameras? Will a function like this cause desync? (It runs every 0.2 seconds... you know, the camera is locked on the player's hero.)

JASS:

function AAA takes nothing returns nothing
local integer a = 0
loop
exitwhen a > 12
if GetLocalPlayer() == Player(a) then
call PanCameraTo(GetUnitX(usg_SomeUnit[a]),GetUnitY(usg_SomeUnit[a]))
endif
set a = a + 1
endloop
endfunction

Diablo-dk · May 12, 2007

Cameras doesn't desync.
look at "CameraSetTargetNoiseForPlayer"

JASS:

function CameraSetTargetNoiseForPlayer takes player whichPlayer, real magnitude, real velocity returns nothing
    if (GetLocalPlayer() == whichPlayer) then
        // Use only local code (no net traffic) within this block to avoid desyncs.
        call CameraSetTargetNoise(magnitude, velocity)
    endif
endfunction

Kixer · May 12, 2007

So GetLocalPlayer() doesnt Desync on any visual functions. But if the function creates an ingame object it will Desync?
Purple said that it only Desyncs when the unit dies, so when the unit is alive will two different players see different units at the same place doing the same thing untill that unit Casts a spell,attacks,is attacked or plays animation other unit doesnt have. Because all those actions require things that are specific to the unit?

PurplePoot · May 12, 2007

Assuming they have the same min-max damage and health (anything that affects combat will desynch if it's changed)

So basically, you can mess with the art (Uber Spell: makes your hero invisible to enemies for 30 seconds)

Kixer · May 12, 2007

Ok thanks for clearing that up Purple...

paskovich · May 13, 2007

I heared that we have to be careful with cameras... Anyway, it's just good that we don't have to.

offtopic: It seems PurplePoot is the offical post-factory with 70-80 post / 3 days nice

Kixer · May 13, 2007

Hmmm maybe thats because cameras are objects? But im not sure...
That reminds me, what other things cause a game to Desync?
[offtopic] He is churning out the posts isnt he? Wasnt he on like 1800 less than a month ago!?!

Diablo-dk · May 13, 2007

Only use GetLocalPlayer() for visual effects:
showing fade filer, showing multiboards, changing vertex color, showing special effects.
ANY creation of an object is risky with GetLocalPlayer()
also, i'm pretty sure changing time of day will cause a desync.
I never heard anything about cameras being risky with LocalPlayer, Many blizzard.j functions use GetLocalPlayer() in displaying text and changing camera for 1 player, so i dont think you should be afraid to use them.

PurplePoot · May 13, 2007

Pan Camera As Necessary desynchs for some weird reason (it's local)

The other ones are fine

Offtopic: So? Atleast they're not spam

Kixer · May 13, 2007

Ok, but are there any other things that Desync a game that dont include GetLocalPlayer()?
[offtopic] Theres nothing wrong with it, apart from the fact your so helpful you make the rest of us look bad :smile:

PurplePoot · May 13, 2007

Desynchs without GetLocalPlayer? I'd be surprised, well, except for the things that are different per player. Eg.

JASS:

constant native GetCameraField              takes camerafield whichField returns real
constant native GetCameraTargetPositionX    takes nothing returns real
constant native GetCameraTargetPositionY    takes nothing returns real
constant native GetCameraTargetPositionZ    takes nothing returns real
constant native GetCameraTargetPositionLoc  takes nothing returns location

UnMi · May 13, 2007

Er, I think it's way different.
I think GetLocalPlayer would cause a desync if the created effect/scenario/object or what ever for that single player is too much to be unique.
Like, things that are less striking would be floating texts, multiboards, or game texts, but if comes to a real unit or effect, then it's desyncs for sure.
What made me to think this way was that I managed to create a cine-filter for specific players only, a cine-filter such as "White-Mask".
Using CinematicFadeBJ alone with GetLocalPlayer did a desync, so I like, did

JASS:

call CinematicFadeBJ(bj_CINEFADETYPE_FADEOUT,0.00,"ReplaceableTextures\\CameraMasks\\White_mask.blp",250.00,250.00,250.00,0.00)
call DisplayCineFilter(false)
call EnableUserUI(true)

then

JASS:

if (GetLocalPlayer == p) then 
    call DisplayCineFilter(true)
    call EnableUserUI(false)
endif

for affected players only, which worked.

PurplePoot · May 13, 2007

I think GetLocalPlayer would cause a desync if the created effect/scenario/object or what ever for that single player is too much to be unique.

Art doesn't always desynch. This works;

JASS:

local string path = "Abilities\\Spells\\(bleh)"
if GetLocalPlayer() != (yourplayer) then
    set path = ""
endif
call AddSpecialEffect( path, ... )

UnMi · May 13, 2007

Wow, really? So you can like, create a special effect for only one user? Never thought this was possible, but I bet that special effect has to be nothing big or striking.
Create 10 like those and you get your desync, I guess.

PurplePoot · May 13, 2007

Never had desynch problems with it, and I use it all the time

paskovich · May 14, 2007

Purple, you said, these things desync only when they are killed/destroyed. What if you create an effect this way:

JASS:

local string path = "<effect path>"
if GetLocalPlayer() != <player> then
    set path = ""
endif
call DestroyEffect(AddSpecialEffect(path,<x>,<y>))

PurplePoot · May 14, 2007

I meant for units. I've never had problems with effects desynching under that method.

Diablo-dk · May 14, 2007

I bet the above function will work.
It desyncs when the unit dies(IF it has same hp, dmg blabla)
but if it doesent have the same hp, dmg blabla, then a desync can happen even whenever it takes damage.
Desyncs seem to be easy to avoid, just watch out for things that creates a new object(as this is what usually causes a desync)

The best place to learn more about desyncs and usage of GetLocalPlayer() would be www.wc3jass.com.

Zergleb · May 21, 2007

You can read the last line if you don't wanna read.

I had a bug once in one of my maps that desynced people, It had to do with making sounds quieter if the players camera was further away. So what I did was run a pick every player loop and if picked player equals LocalPlayer then it set the volume of the sound(Yes unnecessary) according to the distance of the camera.

Now this caused desyncs and the reason I think is why is because I heard that if you call GetLocalPlayer() inside of something that is being ran for a local player it causes a desync. This could be for timing issues? I dunno. but GetCameraPosition() calls for local player.

So in conclusion I'm pretty certain calling GetLocalPlayer() or camera natives that run for a local player can not be ran for a local player.(Like calling GetLocalPlayer for a Local player) and yes, taking this out of the function fixed it.

daxtreme · Jun 7, 2007

PurplePoot said:
Pan Camera As Necessary desynchs for some weird reason (it's local)

The other ones are fine

Blizzard explains it efficiently in the blizzard.j

JASS:

function SmartCameraPanBJ takes player whichPlayer, location loc, real duration returns nothing
    local real dist
    if (GetLocalPlayer() == whichPlayer) then
        // Use only local code (no net traffic) within this block to avoid desyncs.

        set dist = DistanceBetweenPoints(loc, GetCameraTargetPositionLoc())
        if (dist >= bj_SMARTPAN_TRESHOLD_SNAP) then
            // If the user is too far away, snap the camera.
            call PanCameraToTimed(GetLocationX(loc), GetLocationY(loc), 0)
        elseif (dist >= bj_SMARTPAN_TRESHOLD_PAN) then
            // If the user is moderately close, pan the camera.
            call PanCameraToTimed(GetLocationX(loc), GetLocationY(loc), duration)
        else
            // User is close enough, so don't touch the camera.
        endif
    endif
endfunction

> // Use only local code (no net traffic) within this block to avoid desyncs.

Problem is, they don't only use local code in the whole function >_<

Notice the global variables.

edge[d1] · Jun 7, 2007

Problem is, they don't only use local code in the whole function >_<
Notice the global variables.

er, what global variables? all i see are two bj constants and reading constants doesn't split maps. i'm pretty sure that reading gloval variables wouldn't split - only writing would.

does anyone know for fact what's wrong with SmartCameraPanBJ?

-------------

also, i had a sure split (100% of the time) in my map once. it turned out that

Selection - Select TempUnitGroup for CLPlayer

action (that is, SelectGroupForPlayerBJ call) caused desync every time i clicked a button of my custom spell.

PurplePoot · Jun 7, 2007

Tehehehehehe. SmartCameraPanBJ leaks. Never woulda thought that.

And I've never had Selection problems.

daxtreme · Jun 7, 2007

edge[d1];273115 said:
er, what global variables? all i see are two bj constants and reading constants doesn't split maps. i'm pretty sure that reading gloval variables wouldn't split - only writing would.

does anyone know for fact what's wrong with SmartCameraPanBJ?

-------------

also, i had a sure split (100% of the time) in my map once. it turned out that

Selection - Select TempUnitGroup for CLPlayer

action (that is, SelectGroupForPlayerBJ call) caused desync every time i clicked a button of my custom spell.

GetCameraTargetPositionLoc() creates a location.

PurplePoot · Jun 8, 2007

Which also, consequently, causes it to leak.

But yeah, GetCameraTargetPositionLoc() desynchs as soon as you try to use it, even inside GetLocalPlayer, as far as I know

[JASS] Correct use of LocalPlayer()

Similar threads